vlookup函數(shù)的使用方法(入門級)

vlookup函數(shù)的使用方法(初級)

vlookup函數(shù)的使用方法(進(jìn)階)

vlookup函數(shù)的使用方法(高級)

vlookup函數(shù)的使用方法(最高級)

vlookup函數(shù)的使用方法（12種常見錯(cuò)誤）

VLOOKUP函數(shù)的使用方法（入門篇）

VLOOKUP是一個(gè)查找函數(shù)，給定一個(gè)查找的目標(biāo)，它就能從指定的查找區(qū)域中查找返回想要查找到的值。它的基本語法為：

VLOOKUP（查找目標(biāo)，查找范圍，返回值的列數(shù)，精確OR模糊查找)

下面以一個(gè)實(shí)例來介紹一下這四個(gè)參數(shù)的使用

例1：如下圖所示，要求根據(jù)表二中的姓名，查找姓名所對應(yīng)的年齡。

公式：B13 =VLOOKUP(A13,$B$2:$D$8,3,0)

參數(shù)說明：

1.查找目標(biāo)：就是你指定的查找的內(nèi)容或單元格引用。本例中表二A列的姓名就是查找目標(biāo)。我們要根據(jù)表二的“姓名”在表一中A列進(jìn)行查找。

公式：B13 =VLOOKUP(A13,$B$2:$D$8,3,0)

2.查找范圍（VLOOKUP(A13,$B$2:$D$8,3,0) ）：指定了查找目標(biāo)，如果沒有說從哪里查找，EXCEL肯定會(huì)很為難。所以下一步我們就要指定從哪個(gè)范圍中進(jìn)行查找。VLOOKUP的這第二個(gè)參數(shù)可以從一個(gè)單元格區(qū)域中查找，也可以從一個(gè)常量數(shù)組或內(nèi)存數(shù)組中查找。本例中要從表一中進(jìn)行查找，那么范圍我們要怎么指定呢？這里也是極易出錯(cuò)的地方。大家一定要注意，給定的第二個(gè)參數(shù)查找范圍要符合以下條件才不會(huì)出錯(cuò)：

A 查找目標(biāo)一定要在該區(qū)域的第一列。本例中查找表二的姓名，那么姓名所對應(yīng)的表一的姓名列，那么表一的姓名列（列）一定要是查找區(qū)域的第一列。象本例中，給定的區(qū)域要從第二列開始，即$B$2:$D$8，而不能是$A$2:$D$8。因?yàn)椴檎业摹靶彰辈辉?A$2:$D$8區(qū)域的第一列。

B 該區(qū)域中一定要包含要返回值所在的列，本例中要返回的值是年齡。年齡列（表一的D列）一定要包括在這個(gè)范圍內(nèi)，即：$B$2:$D$8，如果寫成$B$2:$C$8就是錯(cuò)的。

3.返回值的列數(shù)（B13 =VLOOKUP(A13,$B$2:$D$8,3,0)）。這是VLOOKUP第3個(gè)參數(shù)。它是一個(gè)整數(shù)值。它怎么得來的呢。它是“返回值”在第二個(gè)參數(shù)給定的區(qū)域中的列數(shù)。本例中我們要返回的是“年齡”，它是第二個(gè)參數(shù)查找范圍$B$2:$D$8的第3列。這里一定要注意，列數(shù)不是在工作表中的列數(shù)（不是第4列），而是在查找范圍區(qū)域的第幾列。如果本例中要是查找姓名所對應(yīng)的性別，第3個(gè)參數(shù)的值應(yīng)該設(shè)置為多少呢。答案是2。因?yàn)樾詣e在$B$2:$D$8的第2列中。

4 精確OR模糊查找（VLOOKUP(A13,$B$2:$D$8,3,0) ），最后一個(gè)參數(shù)是決定函數(shù)精確和模糊查找的關(guān)鍵。精確即完全一樣，模糊即包含的意思。第4個(gè)參數(shù)如果指定值是0或FALSE就表示精確查找，而值為1 或TRUE時(shí)則表示模糊。這里蘭色提醒大家切記切記，在使用VLOOKUP時(shí)千萬不要把這個(gè)參數(shù)給漏掉了，如果缺少這個(gè)參數(shù)默為值為模糊查找，我們就無法精確查找到結(jié)果了。

VLOOKUP函數(shù)的使用方法（初級篇）

一、VLOOKUP多行查找時(shí)復(fù)制公式的問題

VLOOKUP函數(shù)的第三個(gè)參數(shù)是查找返回值所在的列數(shù)，如果我們需要查找返回多列時(shí)，這個(gè)列數(shù)值需要一個(gè)個(gè)的更改，比如返回第2列的，參數(shù)設(shè)置為2，如果需要返回第3列的，就需要把值改為3。如果有十幾列會(huì)很麻煩的。那么能不能讓第3個(gè)參數(shù)自動(dòng)變呢？向后復(fù)制時(shí)自動(dòng)變?yōu)?，3，4，5...

在EXCEL中有一個(gè)函數(shù)COLUMN，它可以返回指定單元格的列數(shù)，比如

=COLUMNS（A1） 返回值1

=COLUMNS（B1） 返回值2

而單元格引用復(fù)制時(shí)會(huì)自動(dòng)發(fā)生變化，即A1隨公式向右復(fù)制時(shí)會(huì)變成B1，C1，D1。這樣我們用COLUMN函數(shù)就可以轉(zhuǎn)換成數(shù)字1，2，3，4...

例：下例中需要同時(shí)查找性別，年齡，身高，體重。

公式：

=VLOOKUP($A13,$B$2:$F$8,COLUMN(B1),0)

公式說明：這里就是使用COLUMN（B1）轉(zhuǎn)化成可以自動(dòng)遞增的數(shù)字。

二、VLOOKUP查找出現(xiàn)錯(cuò)誤值的問題。

1、如何避免出現(xiàn)錯(cuò)誤值

EXCEL2003 在VLOOKUP查找不到，就#N/A的錯(cuò)誤值，我們可以利用錯(cuò)誤處理函數(shù)把錯(cuò)誤值轉(zhuǎn)換成0或空值。

即：=IF(ISERROR(VLOOKUP（參數(shù)略）),'',VLOOKUP（參數(shù)略）

EXCEL2007，EXCEL2010中提供了一個(gè)新函數(shù)IFERROR，處理起來比EXCEL2003簡單多了。

IFERROR（VLOOKUP（）,'')

2、VLOOKUP函數(shù)查找時(shí)出現(xiàn)錯(cuò)誤值的幾個(gè)原因

A、實(shí)在是沒有所要查找到的值

B、查找的字符串或被查找的字符中含有空格或看不見的空字符，驗(yàn)證方法是用=號對比一下，如果結(jié)果是FALSE，就表示兩個(gè)單元格看上去相同，其實(shí)結(jié)果不同。

C、參數(shù)設(shè)置錯(cuò)誤。VLOOKUP的最后一個(gè)參數(shù)沒有設(shè)置成1或者是沒有設(shè)置掉。第二個(gè)參數(shù)數(shù)據(jù)源區(qū)域，查找的值不是區(qū)域的第一列，或者需要反回的字段不在區(qū)域里，參數(shù)設(shè)置在入門講里已注明，請參閱。

D、數(shù)值格式不同，如果查找值是文本，被查找的是數(shù)字類型，就會(huì)查找不到。解決方法是把查找的轉(zhuǎn)換成文本或數(shù)值，轉(zhuǎn)換方法如下：

文本轉(zhuǎn)換成數(shù)值：*1或--或/1

數(shù)值轉(zhuǎn)抱成文本：&''

VLOOKUP函數(shù)的使用方法（進(jìn)階篇）

學(xué)習(xí)VLOOKUP的進(jìn)階篇：VLOOKUP的模糊查找。

一、字符的模糊查找

在A列我們知道如何查找型號為“AAA”的產(chǎn)品所對應(yīng)的B列價(jià)格，即：

=VLOOKUP（C1,A:B,2,0)

如果我們需要查找包含“AAA”的產(chǎn)品名稱怎么表示呢？如下圖表中所示。

公式：

=VLOOKUP('*'&A10&'*',A2:B6,2,0)

公式說明：VLOOKUP的第一個(gè)參數(shù)允許使用通配符“*”來表示包含的意思，把*放在字符的兩邊，即'*' & 字符 & '*'。

二、數(shù)字的區(qū)間查找

數(shù)字的區(qū)間查找即給定多個(gè)區(qū)間，指定一個(gè)數(shù)就可以查找出它在哪個(gè)區(qū)間并返回這個(gè)區(qū)間所對應(yīng)的值。

在VLOOKUP入門中我們提示VLOOKUP的第4個(gè)參數(shù)，如果為0或FALSE是精確查找，如果是1或TRUE或省略則為模糊查找，那么實(shí)現(xiàn)區(qū)間查找正是第4個(gè)參數(shù)的模糊查找應(yīng)用。

首先我們需要了解一下VLOOKUP函數(shù)模糊查找的兩個(gè)重要規(guī)則：

1、引用的數(shù)字區(qū)域一定要從小到大排序。雜亂的數(shù)字是無法準(zhǔn)確查找到的。如下面A列符合模糊查找的前題，B列則不符合。

2、模糊查找的原理是：給一定個(gè)數(shù)，它會(huì)找到和它最接近，但比它小的那個(gè)數(shù)。詳見下圖說明。

最后看一個(gè)實(shí)例：

【例】：如下圖所示，要求根據(jù)上面的提成比率表，在提成表計(jì)算表中計(jì)算每個(gè)銷售額的提成比率和提成額。

公式：=VLOOKUP(A11,$A$3:$B$7,2)

公式說明：

1、上述公式省略了VLOOKUP最后一個(gè)參數(shù)，相當(dāng)于把第四個(gè)參數(shù)設(shè)置成1或TRUE。這表示VLOOKUP要進(jìn)行數(shù)字的區(qū)間查找。

2、圖中公式中在查找5000時(shí)返回比率表0所對應(yīng)的比率1%，原因是0和10000與5000最接近，但VLOOKUP只選比查找值小的那一個(gè)，所以公式會(huì)返回0所對應(yīng)的比率1%。

VLOOKUP函數(shù)的使用方法(高級篇)

學(xué)習(xí)VLOOKUP函數(shù)的高級應(yīng)用部分-VLOOKUP函數(shù)的數(shù)組應(yīng)用。

一、VLOOKUP的反向查找。

一般情況下，VLOOKUP函數(shù)只能從左向右查找。但如果需要從右向右查找，則需要把區(qū)域進(jìn)行“乾坤大挪移”，把列的位置用數(shù)組互換一下。

例1：要求在如下圖所示表中的姓名反查工號。

公式：

=VLOOKUP(A9,IF({1,0},B2:B5,A2:A5),2,0)

公式剖析：

1、這里其實(shí)不是VLOOKUP可以實(shí)現(xiàn)從右至右的查找，而是利用IF函數(shù)的數(shù)組效應(yīng)把兩列換位重新組合后，再按正常的從左至右查找。

2、IF（{1,0},B2:B5,A2:A5)這是本公式中最重要的組成部分。在EXCEL函數(shù)中使用數(shù)組時(shí)（前提時(shí)該函數(shù)的參數(shù)支持?jǐn)?shù)組），返回的結(jié)果也會(huì)是一個(gè)數(shù)組。這里1和0不是實(shí)際意義上的數(shù)字，而是1相關(guān)于TRUE，0相當(dāng)于FALSE，當(dāng)為1時(shí)，它會(huì)返回IF的第二個(gè)參數(shù)（B列），為0時(shí)返回第二個(gè)參數(shù)（A列）。根據(jù)數(shù)組運(yùn)算返回?cái)?shù)組，所以使用IF后的結(jié)果返回一個(gè)數(shù)組（非單元格區(qū)域）：

{'張一','A001';'趙三','A002';'楊五','A003';'孫二','A004'}

二、VLOOKUP函數(shù)的多條件查找。

VLOOKUP函數(shù)需要借用數(shù)組才能實(shí)現(xiàn)多條件查找。

例2：要求根據(jù)部門和姓名查找C列的加班時(shí)間。

分析：我們可以延用例1的思路，我們的努力方向不是讓VLOOKUP本身實(shí)現(xiàn)多條件查找，而是想辦法重構(gòu)一個(gè)數(shù)組。多個(gè)條件我們可以用&連接在一起，同樣兩列我們也可以連接成一列數(shù)據(jù)，然后用IF函數(shù)進(jìn)行組合。

公式：

{=VLOOKUP(A9&B9,IF({1,0},A2:A5&B2:B5,C2:C5),2,0)}

公式剖析：

1、A9&B9 把兩個(gè)條件連接在一起。把他們做為一個(gè)整體進(jìn)行查找。

2、A2:A5&B2:B5，和條件連接相對應(yīng)，把部分和姓名列也連接在一起，作為一個(gè)待查找的整體。

3、IF({1,0},A2:A5&B2:B5,C2:C5) 用IF（{1，0}把連接后的兩列與C列數(shù)據(jù)合并成一個(gè)兩列的內(nèi)存數(shù)組。按F9后可以查看的結(jié)果為：

{'銷售張一',1;'銷售趙三',5;'人事楊五',3;'銷售趙三',6}

4、完成了數(shù)組的重構(gòu)后，接下來就是VLOOKUP的基本查找功能了，另外公式中含有多個(gè)數(shù)據(jù)與多個(gè)數(shù)據(jù)運(yùn)算(A2:A5&B2:B5),，所以必須以數(shù)組形式輸入，即按ctrl+shift后按ENTER結(jié)束輸入。

三、VLOOKUP函數(shù)的批量查找。

VLOOKUP一般情況下只能查找一個(gè)，那么多項(xiàng)該怎么查找呢？

例3 要求把如圖表中所有張一的消費(fèi)金額全列出來

分析：經(jīng)過前面的學(xué)習(xí)，我們也有這樣一個(gè)思路，我們在實(shí)現(xiàn)復(fù)雜的查找時(shí)，努力的方向是怎么重構(gòu)一個(gè)查找內(nèi)容和查找的區(qū)域。要想實(shí)現(xiàn)多項(xiàng)查找，我們可以對查找的內(nèi)容進(jìn)行編號，第一個(gè)出現(xiàn)的是后面連接1，第二個(gè)出現(xiàn)的連接2。

公式：

{=VLOOKUP(B$9&ROW(A1),IF({1,0},$B$2:$B$6&COUNTIF(INDIRECT('b2:b'&ROW($2:$6)),B$9),$C$2:$C$6),2,)}

公式剖析：

1、B$9&ROW(A1) 連接序號，公式向下復(fù)制時(shí)會(huì)變成B$9連接1，2，3

2、給所有的張一進(jìn)行編號。要想生成編號，就需要生成一個(gè)不斷擴(kuò)充的區(qū)域（INDIRECT('b2:b'&ROW($2:$6))，然后在這個(gè)逐行擴(kuò)充的區(qū)域內(nèi)統(tǒng)計(jì)“張一”的個(gè)數(shù)，在連接上$B$2:$B$6后就可以對所有的張一進(jìn)行編號了。

3、IF（{1，0}把編號后的B列和C組重構(gòu)成一個(gè)兩列數(shù)組

通過以上的講解，我們需要知道，VLOOKUP函數(shù)的基本用法是固定的，要實(shí)現(xiàn)高級查找，就需要借助其他函數(shù)來重構(gòu)查找內(nèi)容和查找數(shù)組。

VLOOKUP函數(shù)的使用方法(最高級篇)

vlookup的一個(gè)關(guān)鍵應(yīng)用：跨多表查找。

【例】工資表模板中，每個(gè)部門一個(gè)表。

在查詢表中，要求根據(jù)提供的姓名，從銷售~綜合5個(gè)工作表中查詢該員工的基本工資。

分析：

如果，我們知道A1是銷售部的，那么公式可以寫為：

=VLOOKUP(A2,銷售!A:G,7,0)

如果，我們知道A1可能在銷售或財(cái)務(wù)表這2個(gè)表中，公式可以寫為：

=IFERROR(VLOOKUP(A2,銷售!A:G,7,0),VLOOKUP(A2,財(cái)務(wù)!A:G,7,0))

意思是，如果在銷售表中查找不到(用iferror函數(shù)判斷)，則去財(cái)務(wù)表中再查找。

如果，我們知道A1可能在銷售、財(cái)務(wù)或服務(wù)表中，公式可以再次改為：

=IFERROR(VLOOKUP(A2,銷售!A:G,7,0),IFERROR(VLOOKUP(A2,財(cái)務(wù)!A:G,7,0),VLOOKUP(A2,!A:G,7,0)))

意思是從銷售表開始查詢，前面的查詢不到就到后面的表中查找。

如果，有更多的表，如本例中5個(gè)表，那就一層層的套用下去。這也是提供的VLOOKUP多表查找

方法1：

=IFERROR(VLOOKUP(A2,服務(wù)!A:G,7,0),IFERROR(VLOOKUP(A2,人事!A:G,7,0),IFERROR(VLOOKUP(A2,綜合!A:G,7,0),IFERROR(VLOOKUP(A2,財(cái)務(wù)!A:G,7,0),IFERROR(VLOOKUP(A2,銷售!A:G,7,0),'無此人信息')))))

如果你想簡化一下公式，以適合在更多的表中查詢，提供一個(gè)思路，只是公式簡單了，理解起來卻難了。這里你只需要學(xué)會(huì)怎么修改公式套用就可以了。

方法2：

=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({'銷售';'服務(wù)';'人事';'綜合';'財(cái)務(wù)'}&'!a:a'),A2),{'銷售';'服務(wù)';'人事';'綜合';'財(cái)務(wù)'})&'!a:g'),7,0)

你只需要修改以下部分，就可以直接套用

• A2：查找的內(nèi)容

• {''}：大括號內(nèi)是要查找的多個(gè)工作表名稱，用逗號分隔

• a:a :本例是姓名在各個(gè)表中的A列，如果在B列則為b:b

• a:g ：vlookup查找的區(qū)域

• 7：是vlookup第3個(gè)參數(shù)，相對應(yīng)的列數(shù)。你懂的。

公式思路說明：

1、確定員工是在哪個(gè)表中。這里利用countif函數(shù)可以多表統(tǒng)計(jì)來分雖計(jì)算各個(gè)表中該員工存在的個(gè)數(shù)。

2、利用lookup(1,0/(數(shù)組),數(shù)組) 結(jié)構(gòu)取得工作表的名稱

3、利用indirec函數(shù)把字符串轉(zhuǎn)換成單元格引用。

4、利用vlookup查找。

vlookup函數(shù)的跨表查找，新手同學(xué)建議用iferror+vlookup的模式，公式雖然長，但容易理解且公式不容易出錯(cuò)。如果你有一定基礎(chǔ)，倒可以試試第2種方法。另外，如果工作表有幾十個(gè)或更多，就需要使用宏表函數(shù)get.workbook來獲取所有工作表的名稱，然后應(yīng)用到公式中。

VLOOKUP函數(shù)的使用方法(12種常見錯(cuò)誤)

一、函數(shù)參數(shù)使用錯(cuò)誤。

第1種：第2個(gè)參數(shù)區(qū)域設(shè)置錯(cuò)誤之1。

例：如下圖所示，根據(jù)姓名查找齡時(shí)產(chǎn)生錯(cuò)誤。

錯(cuò)誤原因: vlookup函數(shù)第二個(gè)參數(shù)是查找區(qū)域，該區(qū)域的第1列有一個(gè)必備條件，就是查找的對象（A9），必須對應(yīng)于區(qū)域的第1列。本例中是根據(jù)姓名查找的，那么，第二個(gè)參數(shù)姓名必須是在區(qū)域的第1列位置，而上述公式中姓名列是在區(qū)域A1：E6的第2列。所以公式應(yīng)改為：

=VLOOKUP(A9,B1:E6,3,0)

第2種：第2個(gè)參數(shù)區(qū)域設(shè)置錯(cuò)誤之2。

例2 如下圖所示根據(jù)姓名查找職務(wù)時(shí)產(chǎn)生查找錯(cuò)誤。

錯(cuò)誤原因：本例是根據(jù)姓名查找職務(wù)，可大家注意一下，第2個(gè)參數(shù)B1:D6根本就沒有包括E列的職務(wù)，當(dāng)然會(huì)產(chǎn)生錯(cuò)誤了。所以公式應(yīng)改為：

=VLOOKUP(A9,B1:E6,4,0)

第3種：第4個(gè)參數(shù)少了或設(shè)置錯(cuò)誤。

例3，如下圖所示根據(jù)工號查找姓名

錯(cuò)誤原因：vlookup第四個(gè)參數(shù)為0時(shí)表示精確查找，為1或省略時(shí)表示模糊查找。如果忘了設(shè)置第4個(gè)參數(shù)則會(huì)被公式誤以為是故意省略，按模糊查找進(jìn)行。當(dāng)區(qū)域也不符合模糊查找規(guī)則時(shí)，公式就會(huì)返回錯(cuò)誤值。所以公式應(yīng)改為。

=VLOOKUP(A9,A1:D6,2,0)

或 =VLOOKUP(A9,A1:D6,2,) 注：當(dāng)參數(shù)為0時(shí)可以省略，但必須保留“,”號。

二、數(shù)字格式不同，造成查找錯(cuò)誤。

第4種：查找為數(shù)字，被查找區(qū)域?yàn)槲谋拘蛿?shù)字。

例4：如下圖所示根據(jù)工號查找姓名，查找出現(xiàn)錯(cuò)誤。

錯(cuò)誤原因：在vlookup函數(shù)查找過程中，文本型數(shù)字和數(shù)值型數(shù)字會(huì)被認(rèn)為不同的字符。所以造成無法成功查找。

解決方案：把查找的數(shù)字在公式中轉(zhuǎn)換成文本型，然后再查找。即：

=VLOOKUP(A9&'',A1:D6,2,0)

第5種：查找格式為文本型數(shù)字，被查找區(qū)域?yàn)閿?shù)值型數(shù)字。

例5：如下圖所示根據(jù)工號查找姓名，查找出現(xiàn)錯(cuò)誤

錯(cuò)誤原因：同4

解決方法：把文本型數(shù)字轉(zhuǎn)換成數(shù)值型。即：

=VLOOKUP(A9*1,A1:D6,2,0)

三、引用方式使公式復(fù)制后產(chǎn)生錯(cuò)誤。

第6種：沒有正確的使用引用方式，造成在復(fù)制公式后區(qū)域發(fā)生變動(dòng)引起錯(cuò)誤。

例6，如下圖所示，當(dāng)C9的公式復(fù)制到C10和C11后，C10公式返回錯(cuò)誤值。

錯(cuò)誤原因：由于第二個(gè)參數(shù)A2:D6是相對引用，所以向下復(fù)制公式后會(huì)自動(dòng)更改為A3:D7,而A10中的工號A01所在的行，不在A3:D7區(qū)域中，從而造成查找失敗。

解決方案：把第二個(gè)參數(shù)的引用方式由相對引用改為絕對引用即可。

B9公式改為：

=VLOOKUP(A9,$A$2:$D$6,2,0）

四、多余的空格或不可見字符

第7種：數(shù)據(jù)表中含有多余的空格。

例7 如下圖所示，由于A列工號含有多余的空格，造成查找錯(cuò)誤。

錯(cuò)誤原因：多一個(gè)空格，用不帶空格的字符查找當(dāng)然會(huì)出錯(cuò)了。

解決方案：1 手工替換掉空格。建議用這個(gè)方法

2 在公式中用trim函數(shù)替換空格而必須要用數(shù)據(jù)公式形式輸入。

即：=VLOOKUP(A9,TRIM(A1:D6),2,0) 按ctrl+shift+enter輸入后數(shù)組形式為 {=VLOOKUP(A9,TRIM(A1:D6),2,0)}

第8種：類空格但非空格的字符。

在表格存在大量的“空格”，但又用空格無法替換掉時(shí)，這些就是類空格的不可見字符，這時(shí)可以“以其人之道還之其人之身”，直接在單元格中復(fù)制不可見字符粘貼到替換窗口，替換掉即可。

第9種：不可見字符的影響

例： 如下圖所示的A列中，A列看不去不存在空格和類空格字符，但查找結(jié)果還是出錯(cuò)。

出錯(cuò)原因：這是從網(wǎng)頁或數(shù)據(jù)庫中導(dǎo)入數(shù)據(jù)時(shí)帶來的不可見字符，造成了查找的錯(cuò)誤。

解決方案：在A列后插入幾列空列，然后對A列進(jìn)行分列操作（數(shù)據(jù) - 分列），即可把不可見字符分離出去。

在日常vlookup函數(shù)查找錯(cuò)誤示例中，第8種是最常見的一種錯(cuò)誤之一。同學(xué)遇到vlookup查找錯(cuò)誤時(shí)，如果參數(shù)設(shè)置沒有問題，就看一下數(shù)據(jù)表中有沒有多余的空格。

第10種：反向查找vlookup不支持產(chǎn)生的錯(cuò)誤。

例10 如下圖所示的表中，根據(jù)姓名查找工號，結(jié)果返回了錯(cuò)誤。

錯(cuò)誤原因：vlookup不支持反向查找。

解決方法：1 用if函數(shù)重組區(qū)域，讓兩列顛倒位置。

=VLOOKUP(D8,IF({0,1},D2:D4,E2:E4),2,0)

2 用index+match組合實(shí)現(xiàn)。

=INDEX(D2:D4,MATCH(D8,E2:E4,0))

第11種：通配符引起的查找錯(cuò)誤

例11，如下圖所示，根據(jù)區(qū)間查找提成返回錯(cuò)誤值。

錯(cuò)誤原因：~用于查找通配符，如果在vlookup公式中出現(xiàn)，會(huì)被認(rèn)為特定用途，非真正的~。如在表格中查找3*6 ，356，376也被查找到。

如果精確查找3*6，需要使用~，如下圖所示。

解決方法：用~~就可以表示查找~了。所以公式可以修改為

=VLOOKUP(SUBSTITUTE(A8,'~','~~'),A2:B4,2,0)

第12種：vlookup函數(shù)第1個(gè)參數(shù)不直接支持?jǐn)?shù)組形式產(chǎn)生的錯(cuò)誤

例12：如下圖所示，同時(shí)查找A和C產(chǎn)品的和，然后用SUM求和。

錯(cuò)誤原因: VLOOKUP第一個(gè)參數(shù)不能直接用于數(shù)組。

解決方法：利用N/T+IF結(jié)構(gòu)轉(zhuǎn)化一下數(shù)組，如果不了解N/T+IF結(jié)構(gòu)用法，公式修改為：

=SUM(VLOOKUP(T(IF({1},A8:B8)),A2:B5,2,))

vlookup函數(shù)常見的12種錯(cuò)誤我們介紹完了，掌握了這些技巧可能在以后的工作中不再會(huì)被vlookup公式困繞了

▎本文轉(zhuǎn)自：Excel精英培訓(xùn)（ID：excelpx-tete）