1、sum()函數(shù)如果參數(shù)是一個(gè)數(shù)組或引用，則只計(jì)算其中的數(shù)字。數(shù)組或引用中的空白單元格、邏輯值或文本將被忽略。（看下圖）
2、sum()函數(shù)如果任意參數(shù)為錯(cuò)誤值或?yàn)椴荒苻D(zhuǎn)換為數(shù)字的文本，Excel 將會(huì)顯示錯(cuò)誤。
要計(jì)算出結(jié)果，可以：
· H4{=SUM(IFERROR(H1:H3,0))}
· H4=SUMIF(H1:H3,"<9e+307")
· H4{=SUM(IF(ISERR(H1:H3),0,H1:H3))}
· H4{=SUM(IF(ISERROR(H1:H3),0,H1:H3))}
第一、第三和第四三個(gè)數(shù)組公式，外面的大括號不是手動(dòng)加給的，而是Shift+Ctrl+Enter獲取的，我們叫它區(qū)域數(shù)組公式。
依據(jù)以上兩點(diǎn)說明，SUM()函數(shù)求一行既有文本又有數(shù)字的區(qū)域，它忽略文本只計(jì)算數(shù)字。
一、SUM()快速求和介紹：
1、對三張表匯總求和：
1第一種方法：=sum('*'!b2) 一般的方法：
步驟：在匯總表B2輸入sum('*'!b2)按住Ctrl+Enter
· 第二種方法：按住Shift鍵直接鼠標(biāo)點(diǎn)擊最后一張求和工作表;
· 按住Shift鍵直接鼠標(biāo)點(diǎn)擊最后一張求和工作表。
2、 對一張表每個(gè)合計(jì)求和：
3、 合并單元格求和：
這個(gè)實(shí)例網(wǎng)上比較多，我在W10，微軟2013版操作可以實(shí)現(xiàn)，sum()合并單元格其他版本無法實(shí)現(xiàn)。另外：快速求和快捷方式用
二、SUM()函數(shù)求和介紹：
=SUM() 、=SUMPRODUCT()=、SUBTOTAL()、=SUMIF()、=SUMIFS()
(一)、Sum()區(qū)域求和與SUMPRODUCT()區(qū)域求和，Sum()函數(shù)必須使用Shift+Ctrl+Enter區(qū)域數(shù)組結(jié)束，而SUMPRODUCT()函數(shù)不使用Shift+Ctrl+Enter，因?yàn)樗莾?nèi)存數(shù)組，內(nèi)存數(shù)組一般要比區(qū)域數(shù)組計(jì)算快。比如：計(jì)算1到100的和。
l Q3{=SUM(ROW(1:100))}
l Q4=SUMPRODUCT(ROW(1:100))
a) 計(jì)算車間女職工工資多少?
l E10{=SUM((RIGHT(A10:A16,2)="車間")*(B10:B16="女")*C10:C16)}
l F10=SUMPRODUCT((RIGHT(A10:A16,2)="車間")*(B10:B16="女")*C10:C16)
l G10=SUMIFS(C10:C16,A10:A16,"*車間",B10:B16,"女")
l H10=SUMPRODUCT(--NOT(ISERR(FIND("車間",A10:A16)))*(B10:B16="女")*C10:C16)
l I10=SUMPRODUCT(--NOT(ISERR(SEARCH("*車間",A10:A16)))*(B10:B16="女")*C10:C16)
第一個(gè)公式解釋：RIGHT(A10:A16,2)="車間"提取右邊A10:A16的兩個(gè)字段等于"車間"及(B10:B16="女")的工資C10:C16之和，(RIGHT(A10:A16,2)="車間")必須要括起來。
b) 計(jì)算車間男女工資之差
l E14=SUM(SUMIFS(C10:C16,A10:A16,"*車間",B10:B16,{"男","女"})*{1,-1})
公式解釋：B10:B16,{"男","女"})*{1,-1} ,B10:B16是性別， SUMIFS第二參數(shù)，第三參數(shù),{"男","女"}是一個(gè)常量數(shù)組，后面 {1,-1}將前面的男和女轉(zhuǎn)換成正負(fù)數(shù)值，從而計(jì)算出男女工資之差。
l F14=SUMPRODUCT((RIGHT(A10:A16,2)="車間")*(B10:B16={"男","女"})*(C10:C16)*{1,-1})
l G14{=SUM((RIGHT(A10:A16,2)="車間")*(B10:B16={"男","女"})*(C10:C16)*{1,-1})}
a) 匯總車間女職工人數(shù)
l E18{=SUM((B10:B16="女")*(RIGHT(A10:A16,2)="車間"))}
l F18=SUMPRODUCT((B10:B16="女")*(RIGHT(A10:A16,2)="車間"))
b) 求男職工人數(shù)
l E21{=SUM((B10:B16="男")*1)}
l F21=SUMPRODUCT((B10:B16="男")*1)
c) 求女職工工資最高前倆位工資之總和
l E24{=SUM(SUMPRODUCT(LARGE(IF(B10:B16=B14,C10:C16,),{1,2})))}
l F24{=SUM(LARGE(IF(B10:B16=B15,C10:C16,),ROW(1:2)))}
d) 求男職工大于100的工資和
l E27{=SUM((B10:B16="男")*(C10:C16>100)*C10:C16)}
l F27=SUMPRODUCT((B10:B16="男")*(C10:C16>100)*C10:C16)
e) 求職工大于100，小于800的工資之和
l E30{=SUM((C10:C16>100)*(C10:C16<800)*C10:C16)}
l F30=SUMPRODUCT((C10:C16>100)*(C10:C16<800)*C10:C16)
l G30=SUM(SUMIF(C10:C16,"<"&{200,800})*{-1,1})
f) 求一至四個(gè)車間男職工人數(shù)
l E43{=SUM((A10:A16={"一","二","三","四"}&"車間")*(B10:B16="男")*C10:C16)}
l F43=SUMPRODUCT((A10:A16={"一","二","三","四"}&"車間")*(B10:B16="男")*C10:C16)
(二) 隔行求和
l J3{=SUM((MOD(COLUMN($B3:$I3),2)=0)*$B3:$I3)}
l K3=SUMPRODUCT((MOD(COLUMN($B3:$I3),2)=1)*$B3:$I3)
(三) 求前三名銷售人員銷售額
l H2{=SUM(LARGE(C2:C9,{1,2,3}))}
l I2{=SUM(LARGE(C2:C9,ROW(1:3)))}
l H3=SUMPRODUCT(LARGE(C2:C9,{1,2,3}))
l H3=SUMPRODUCT(LARGE(C2:C9,ROW(1:3)))
(四) 求取區(qū)域（B9:K10）去掉一個(gè)最小值去掉一個(gè)最大值之和
l F9=SUM((B6:K7))-SUM(SMALL(B6:K7,1))-SUM(LARGE(B6:K7,1))
l E9=SUMPRODUCT((B6:K7))-SUM(SMALL(B6:K7,1))-SUM(LARGE(B6:K7,1))
(五) 計(jì)算排名
l C2{=SUM(($B$2:$B$7>B2)/COUNTIF($B$2:$B$7,$B$2:$B$7))+1}
l B2=SUMPRODUCT(($B$2:$B$7>B2)/COUNTIF($B$2:$B$7,$B$2:$B$7))+1
l K2=CONCATENATE(H2,TEXT(SUM((H$2:H$22=$H2)*($J$2:$J$22>=J2)/COUNTIF(J$2:J$22,$J$2:$J$22)),"第0名"))
(六) 求每個(gè)人的所得
l G1{=SUM(IF(ISERR(FIND(F1,C$2:C$10)),0,1)*A$2:A$10*B$2:B$10*(1/(LEN(TRIM(C$2:C$10))-LEN(SUBSTITUTE(TRIM(C$2:C$10),"",))+1)))}
l H1=SUMPRODUCT(ISNUMBER(FIND(F1,C$2:C$10))*A$2:A$10*B$2:B$10*(1/(LEN(TRIM(C$2:C$10))-LEN(SUBSTITUTE(TRIM(C$2:C$10),"",))+1)))
(七) 求某人三科成績之和
l O2{=SUM(($A$2:$A$6=K2)*NOT(ISERR(FIND(B$1:H$1,L2)))*B$2:H$6)}
l O3=SUMPRODUCT(($A$2:$A$6=K3)*NOT(ISERR(FIND(B$1:H$1,L3)))*B$2:H$6)
l N2 =SUM(MMULT(--(TRANSPOSE($B$1:$H$1)=MID(L2,{1,3,5},2)),(ROW($1:$3))^0)*TRANSPOSE(B2:H2))
l M2 =SUMPRODUCT((A$2:A$6=K2)*(1-ISERR(FIND($B$1:$H$1,L2)))*B$2:H$6)
l M3 {=SUM((A$2:A$6=K3)*(1-ISERR(FIND($B$1:$H$1,L3)))*B$2:H$6)}
(八) 返回每個(gè)人最后一次考核分?jǐn)?shù)的平均分
l I2 {=SUM(IF(B3:F10,"",B2:F9))/COUNT(B2:F2)}
l =SUMIF(B3:F10,"",B2:F9)/COUNT(B2:F2)
(九) 求選定公司收入之和
l E4 {=SUM(LOOKUP(A4:C4,B1:L2))}
l F4=SUMPRODUCT(SUMIF(B1:L1,A4:C4,B2:L2))
l C6 =SUM(HLOOKUP(T(IF({1},A4:C4)),$A$1:$L$2,2,FALSE))
l E6{=SUM(HLOOKUP(T(IF(1,A4:C4&{""})),$A$1:$L$2,2,FALSE))}
l D7 {=SUM(COUNTIF(A4:C4,B1:L1)*B2:L2)}
l E7 =SUM(HLOOKUP(T(IF({1},A4:C4)),$A$1:$L$2,2,FALSE))
l D8{ =SUM(OFFSET(A2,,N(IF(1,MATCH(A4:C4,B1:L1,)))))}
l E8{ =SUM(INDEX(B2:L2,N(IF(1,MATCH(A4:C4,B1:L1,)))))}
l D9 {=SUM(N(OFFSET(A2,,MATCH(A4:C4,B1:L1,))))}
l E9{ =MMULT(COUNTIF(A4:C4,B1:L1),TRANSPOSE(B2:L2))}
(十) 做查詢使用
l G2{=IFERROR(SUM(($A$2:$A$7=$E$2)*($B$2:$B$7=$F$2)*C2:C7),"")}
l H2=IFERROR(SUMPRODUCT(($A$2:$A$7=$E$2)*($B$2:$B$7=$F$2)*C2:C7),"")
(十一) 依據(jù)行A2變化求平均值
l A4=SUM(2:2)/SUMIF(2:2,"<>",1:1)
l A6=SUM(2:2)/SUM(OFFSET(A1,,,,COUNT(2:2)))
注意：“<>”的作用是第2行中滿足不為空的對應(yīng)第1行數(shù)值求和。
(十二) 多列 (根據(jù)日期求和)
l C4 =SUM(OFFSET(C4,,MATCH(C$3,D$3:O$3,)):O4)
l G13 =SUM(INDEX($D4:$O4,MATCH($C$3,$D$3:$O$3,0)):O4)
注意：是依據(jù)C3單元格選擇日期計(jì)算
(十三) 提取1至9的數(shù)字并相加求和
計(jì)算A6數(shù)字合計(jì)
l D6 {=SUM(MID(A6,ROW(INDIRECT("1:"&LEN(A6))),1)*1)}
l C6 =SUMPRODUCT(MID(A6,ROW(INDIRECT("1:"&LEN(A6))),1)*1)
計(jì)算文本數(shù)字
l D5 =SUM(MID(A5,ROW(INDIRECT("1:"&LEN(A5))),1)*1)
l C5 =SUMPRODUCT(MID(A5,ROW(INDIRECT("1:"&LEN(A5))),1)*1)
計(jì)算帶有字母的數(shù)字之和
l D4 {=SUM(IFERROR(MID(A4,ROW(INDIRECT("1:"&LEN(A4))),1)/1,0))}
l C4{=SUMPRODUCT(IFERROR(MID(A4,ROW(INDIRECT("1:"&LEN(A4))),1)/1,0))}
(十四) 在篩選狀態(tài)下求合計(jì)
通過B列名稱或C列供應(yīng)商篩選，求總價(jià)：
l I1{=SUM($D2:$D11*$E2:$E11*SUBTOTAL(103,OFFSET($E1,ROW(1:10),)))}
l H1=SUMPRODUCT($D2:$D11*$E2:$E11*SUBTOTAL(103,OFFSET($E1,ROW(1:10),)))
l K1 {=SUM(D2:D11*SUBTOTAL(109,OFFSET(E1,ROW(1:10),)))}
l J1=SUMPRODUCT(D2:D11*SUBTOTAL(109,OFFSET(E1,ROW(1:10),)))
有B1:B10，10個(gè)數(shù)據(jù)，根據(jù)篩選結(jié)果，統(tǒng)計(jì)大于5小于等于30的數(shù)值個(gè)數(shù)。
l H15{=SUM(SUBTOTAL(103,OFFSET(E1,ROW(1:99),))*(E2:E100>=5)*(E2:E100<=30))}
l I15=SUMPRODUCT(SUBTOTAL(103,OFFSET(E1,ROW(1:99),))*(E2:E100>=5)*(E2:E100<=30))
(十五) 匯總6張表數(shù)據(jù)
l B2{=SUM(SUMIF(INDIRECT(ROW($1:$6)&"月!A:A"),"*"&$A2&"*",INDIRECT(ROW($1:$6)&"月!B:B")))}
l B2=SUMPRODUCT(SUMIF(INDIRECT(ROW($1:$6)&"月!A:A"),"*"&$A2&"*",INDIRECT(ROW($1:$6)&"月!B:B")))
全部講解告一段落，總之，SUM()函數(shù)極其強(qiáng)大，不可小覷，也許你還能舉出更多實(shí)例，那說明我還不與您，我還得進(jìn)一步學(xué)習(xí)。因?yàn)椋?60doc無法上傳gif，也無法上傳文件，只能截圖加文字說明，如果需要文件可以短信聯(lián)系。
